Skip to content

Instantly share code, notes, and snippets.

@shieldwed
Created February 8, 2017 21:13
  • Star 0 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
Star You must be signed in to star a gist
Save shieldwed/de48b0c74a240eeaf91e93b7b17ceaac to your computer and use it in GitHub Desktop.
# Maintainer: Alex Taber <aft dot pokemon at gmail dot com>
pkgname=teamviewer
pkgver=12.0.71510
pkgrel=7
pkgdesc='All-In-One Software for Remote Support and Online Meetings'
arch=('i686' 'x86_64')
url='http://www.teamviewer.com'
license=('custom')
options=('!strip')
provides=('teamviewer')
conflicts=('teamviewer-beta')
depends_x86_64=(
'lib32-fontconfig'
'lib32-libpng12'
'lib32-libsm'
'lib32-libxinerama'
'lib32-libxrender'
'lib32-libjpeg6-turbo'
'lib32-libxtst'
'libxtst')
depends_i686=(
'fontconfig'
'libpng12'
'libsm'
'libxinerama'
'libxrender'
'libjpeg6-turbo'
'libxtst')
install=teamviewer.install
source=("https://download.teamviewer.com/download/version_${pkgver%%.*}x/teamviewer_${pkgver}_i386.tar.xz")
sha512sums=('03ff9404a37c1dc7ae72e72c8137232cd51da58a7700190a97ea5e92fee2e2ed27db295d6d4df3a0de6e9eb23a8c6ba1d7a6d8f70f1a3a5046915fabec3cc253')
package() {
# Install
warning "If the install fails, you need to uninstall previous major version of Teamviewer"
install -d "${pkgdir}"/{etc/teamviewer,opt/teamviewer,usr/bin,usr/share/applications,usr/share/icons/hicolor/48x48/apps,var/log/teamviewer12}
cp -dr --no-preserve=ownership teamviewer/{doc,tv_bin} "${pkgdir}"/opt/teamviewer
ln -s /etc/teamviewer "${pkgdir}"/opt/teamviewer/config
ln -s /var/log/teamviewer12 "${pkgdir}"/opt/teamviewer/logfiles
ln -s /opt/teamviewer/tv_bin/script/teamviewer "${pkgdir}"/usr/bin/teamviewer
ln -s /opt/teamviewer/tv_bin/desktop/com.teamviewer.TeamViewer.desktop "${pkgdir}"/usr/share/applications/com.teamviewer.TeamViewer.desktop
ln -s /opt/teamviewer/tv_bin/desktop/teamviewer.png "${pkgdir}"/usr/share/icons/hicolor/48x48/apps/teamviewer.png
ln -s /opt/teamviewer/tv_bin/desktop/teamviewer.png "${pkgdir}"/usr/share/icons/hicolor/48x48/apps/TeamViewer.png
# Additional files
rm \
"${pkgdir}"/opt/teamviewer/tv_bin/xdg-utils/xdg-email \
"${pkgdir}"/opt/teamviewer/tv_bin/desktop/teamviewer.desktop.template
install -D -m0644 "${pkgdir}"/opt/teamviewer/tv_bin/script/teamviewerd.service \
"${pkgdir}"/usr/lib/systemd/system/teamviewerd.service
install -d -m0755 "${pkgdir}"/usr/{share/applications,share/licenses/teamviewer}
ln -s /opt/teamviewer/License.txt \
"${pkgdir}"/usr/share/licenses/teamviewer/LICENSE
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment