a minimum Snell's window shader

Snell.shader

Shader "Snell"
{
    Properties
    {
        _WaterColor ("Water Color", Color) = (0.2, 0.8, 1, 1)
        _Absorption("Absorption (sigma_a)", Color) = (0.3, 0.04, 0.01)
    }
    SubShader
    {
        Tags
        {
            "RenderType"="Opaque" "Queue"="Transparent"
        }
        GrabPass
        {
            "_GrabTexture"
        }
        Pass
        {
            Blend One Zero

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            #define IOR_RATIO_WATER_AIR 1.3333 // n2/n1
            #define F0 0.02 //{(n1-n2)/(n1+n2)}^2

            struct appdata
            {
                float4 vertex : POSITION;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float3 worldPos : TEXCOORD1;
                float4 screenPos : TEXCOORD2;
                float4 vertex : SV_POSITION;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            sampler2D _GrabTexture;

            half3 _WaterColor;
            half3 _Absorption;

            v2f vert(appdata v)
            {
                v2f o;

                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_OUTPUT(v2f, o);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);

                o.vertex = UnityObjectToClipPos(v.vertex);
                o.screenPos = ComputeScreenPos(o.vertex);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                UNITY_TRANSFER_FOG(o, o.vertex);
                return o;
            }

            half4 frag(v2f i) : SV_Target
            {
                UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(i);

                float3 position = i.worldPos;
                half3 view = _WorldSpaceCameraPos - position;
                half depth = length(view);
                view /= depth;

                // 法線を良い感じにする
                half3 normal = half3(0, 1, 0);

                half3 refractDir = refract(view, normal * -1, IOR_RATIO_WATER_AIR);
                half3 cosTheta = dot(normal, refractDir);
                half fresnel = F0 + (1 - F0) * pow(1 - cosTheta, 5);

                // refract color
                float2 screenUV = i.screenPos.xy / i.screenPos.w;
                // uvをなんかいい感じにする（cubemapにしてもいい）
                half3 bgColor = tex2D(_GrabTexture, screenUV).rgb;
                half3 refractColor = bgColor * IOR_RATIO_WATER_AIR * IOR_RATIO_WATER_AIR * (1 - fresnel);

                // 水中からの反射（なんかいい感じにする）
                half3 reflectColor = _WaterColor * fresnel;

                half3 col = refractColor + reflectColor;

                // absorption
                col *= exp(- depth * _Absorption);

                return half4(col, 1);
            }
            ENDCG
        }
    }
}