Maven custom build versions that include jira issue id from branch name

Jenkinsfile

pipeline {
  agent any

  environment {
    V_DEPLOY_VERSION = buildDeployVersion(readMavenPom().getVersion())
  }

  stages {
    stage('Version') {
      steps {
        sh 'printenv'
        sh 'mvn versions:set -DnewVersion=$V_DEPLOY_VERSION'
      }
    }
    stage('Build') {
      steps {
        sh 'mvn clean install'
      }
    }
  }
}


@NonCPS
def extractIssueIdFromBranchName() {
  def matcher = env['BRANCH_NAME'] =~ '^(.*?)([A-Z]+-[0-9]+).*$'
  matcher ? matcher[0][2] : null
}

@NonCPS
def extractBranchFromBranchName() {
  def matcher = env['BRANCH_NAME'] =~ '^(develop)$'
  matcher ? 'DEV' : null
}

@NonCPS
def extractVersionFromPomVersion(pomVersion) {
  def matcher = pomVersion =~ '^([0-9]+.[0-9]+.[0-9]+)(-SNAPSHOT)?$'
  matcher ? matcher[0][1] : pomVersion
}

@NonCPS
def buildTag(branch, issueId) {
  (branch ? branch : issueId) + '-' + env['BUILD_NUMBER'] + '-SNAPSHOT'
}

@NonCPS
def buildDeployVersion(pomVersion) {
  def result = null

  def branch = extractBranchFromBranchName()
  def issueId = extractIssueIdFromBranchName()
  def version = extractVersionFromPomVersion(pomVersion)
  if (branch || issueId) {

    def tag = buildTag(branch, issueId)
    result = version + '.' + tag
  } else {

    result = version
  }

  result
}