A bat script for doing MySQL backups I found lying around.

mysql-backup.bat

@echo off

:: requires US locale system setting

set dbUser=root
set dbPassword=<your-password>
set backupDir="C:\Documents and Settings\username\Desktop\backup\mysql"
set mysqldump="C:\Program Files\MySQL\MySQL Workbench 5.2 CE\mysqldump.exe"
set mysqlDataDir="C:\Documents and Settings\All Users\Application Data\MySQL\MySQL Server 5.1\data"
set zip="C:\Program Files\7-Zip\7z.exe"

:: get date
for /F "tokens=2-4 delims=/ " %%i in ('date /t') do (
	set mm=%%i
	set dd=%%j
	set yy=%%k
)

:: get time
for /F "tokens=5-8 delims=:. " %%i in ('echo.^| time ^| find "current" ') do (
	set hh=%%i
	set min=%%j
)

set dirName=%yy%%mm%%dd%_%hh%%min%

:: switch to data folder
pushd %mysqlDataDir%

for /d %%f in (*) do (
	:: create backup folder
	if not exist %backupDir%\%dirName%\ (
		mkdir %backupDir%\%dirName%
	)
	%mysqldump% --host="localhost" --user=%dbUser% --password=%dbPassword% --single-transaction --add-drop-table --databases %%f > %backupDir%\%dirName%\%%f.sql
	%zip% a -tgzip %backupDir%\%dirName%\%%f.sql.gz %backupDir%\%dirName%\%%f.sql
	del %backupDir%\%dirName%\%%f.sql
)