AHK Script: LMB Renda-kun (for FKG battle auto Go!)

Renda-kun.ahk

; LMB Renda-kun for FLOWER KNIGHT GIRL
; @version 1.2
; @author sin_sin

#NoTrayIcon

DefaultWinTitle := "FLOWER KNIGHT GIRL"

Gui, New, hwndhGui AlwaysOnTop ToolWindow -Resize -MaximizeBox
Gui, Add, Edit, w151 r1 vTargetWinTitle
GuiControl, , TargetWinTitle, %DefaultWinTitle%
Gui, Add, Button, Default, &Start
Gui, Add, Button, , S&top
Gui, Add, Edit, yp-28 xp+50 w100 r1 ReadOnly vMousePos
Gui, Add, Checkbox, yp+32 xp-8 Right vRendaOn, On?
Gui, Add, Checkbox, yp xp+48 Right vFocusOn, Focus?
GuiControl, Disable, RendaOn
GuiControl, Disable, FocusOn
GuiWinX := A_ScreenWidth - 165
Gui, Show, NoActivate X%GuiWinX% Y560, Renda-kun
SetTimer, Update, 500
return

Update:
Gui %hGui%:Default
CoordMode, Mouse, Screen
actWin := WinExist("A")
WinGetTitle, wTitle
WinGetClass, wClass
if (actWin = hGui || wClass = "MultitaskingViewFrame") {
	return
}
GuiControlGet, TargetWinTitle
if (SubStr(wTitle, 1, StrLen(TargetWinTitle)) =  TargetWinTitle) {
	GuiControl, , FocusOn, 1
} else {
	GuiControl, , FocusOn, 0
}
GuiControlGet, RendaOn
GuiControlGet, FocusOn
CoordMode, Mouse, Client
MouseGetPos, mcX, mcY
GuiControl, , MousePos, %  mcX "," mcY " @" wTitle
if (RendaOn && FocusOn) {
	MouseClick, left
}
return

GuiClose:
ExitApp

ButtonStart:
CoordMode, Mouse, Relative
Click -80, 65
GuiControl, , RendaOn, 1
return

ButtonStop:
GuiControl, , RendaOn, 0
return

~*Shift::
SetTimer, Update, Off
return

~*Shift up::
SetTimer, Update, On
return