Archlinux PKGBUILD for slowmovideo-git

PKGBUILD

# Maintainer: ZKenJ <zkenjm@gmail.com>
# Contributor: Cilyan
# Contributor: Dan Serban
# Contributor: sjewo

pkgname=slowmovideo-git
pkgver=20150206
pkgrel=1
pkgdesc="Video slow motion effect via interpolation"
arch=('i686' 'x86_64')
url="http://slowmovideo.granjow.net/index.html"
license=('GPL')
depends=('ffmpeg' 'freeglut' 'glew' 'libjpeg-turbo' 'libpng' 'opencv' 'qt4' 'sdl')
makedepends=('cmake' 'git')
provides=('slowmovideo')
conflicts=('slowmovideo')
source=('git+https://github.com/slowmoVideo/slowmoVideo.git')
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}"/slowmoVideo
  git log -1 --format='%cd' --date=short | tr -d -- '-'
}
 
build() {
  cd "${srcdir}/slowmoVideo"
  # Fix cmake install error
  sed -i '/FIXUP_QT5_EXECUTABLE/ s/${executable}/bin\/${executable}/' src/cmake/DeployQt5.cmake
  sed -i '/install_qt_executable(slowmoUI/ s/${PLUGINS}"/" ""/' src/slowmoVideo/slowmoUI/CMakeLists.txt
  sed -i '/install(TARGETS/ s/DESTINATION "."/BUNDLE DESTINATION . COMPONENT Runtime\n RUNTIME DESTINATION ${DEST} COMPONENT Runtime/' src/slowmoVideo/slowmoUI/CMakeLists.txt

  rm -r build
  mkdir build && cd build
  # disable old test and use of qtkit
  cmake -DUSE_QTKIT=FALSE -DENABLE_TESTS=FALSE -DCMAKE_INSTALL_PREFIX=/usr ../src
  make
}
 
package() {
  cd "${srcdir}/slowmoVideo/build"
  make DESTDIR="${pkgdir}" install
}