area3.clj

(ns area3
  (:require
    [clojure.math   :as math]
    [criterium.core :as crit]))
(set! *warn-on-reflection* true)
(set! *unchecked-math* false)

(definterface IArea2
  (^double area []))

;(require '[clj-java-decompiler.core :refer [decompile]])

(defrecord Square [^double side]
  IArea2
  (area [this]
    (Math/pow side (double 2))))

(defrecord Rectangle [^double width ^double height]
  IArea2
  (area [_]
    (* width height)))

(defrecord Triangle [^double base ^double height]
  IArea2
  (area [_]
    (* 0.5 base height)))

(defrecord Circle [^double radius]
  IArea2
  (area [this]
    (* math/PI (Math/pow radius (double 2)))))

(defn make-random-shape []
  (let [shapes  [:square :rectangle :circle :triangle]
        shape   (rand-nth shapes)]
    (case shape
      :square    (->Square (rand-int 10))
      :rectangle (->Rectangle (rand-int 10) (rand-int 10))
      :triangle  (->Triangle (rand-int 10) (rand-int 10))
      :circle    (->Circle (rand-int 10)))))

(defn total-area [shapes]
  (loop [n (double 0)
         [^IArea2 s & r] shapes]
    (if s
      (recur (+ n (.area s)) r)
      n)))


(def lots-of-shapes (doall (repeatedly 400000 #(make-random-shape))))

(crit/quick-bench (total-area lots-of-shapes))