ArmorPlus 1.12.2 CraftTweaker Integration Samples

armorplus.md

#Name: armorplus.zs
#Author: sokratis12GR

print("Initializing 'armorplus.zs'...");

val dPickaxe = <minecraft:diamond_pickaxe>;
val stick = <ore:stickWood>;
val diamond = <ore:gemDiamond>;

# mods.armorplus.Workbench.addShaped(<output>, <3x3 ingredients>);

mods.armorplus.Workbench.addShaped(dPickaxe,
 [[diamond, diamond, diamond],
  [null, stick, null],
  [null, stick, null]]);

# mods.armorplus.Workbench.remove(<ItemStack>);

mods.armorplus.Workbench.remove(<armorplus:redstone_helmet>);

# mods.armorplus.HighTechBench.addShaped(<output>, <5x5 ingredients>);

mods.armorplus.HighTechBench.addShaped(dPickaxe,
 [[diamond, diamond, diamond, diamond, diamond],
  [null, null, stick, null, null],
  [null, null, stick, null, null],
  [null, null, stick, null, null],
  [null, null, stick, null, null]]);

# mods.armorplus.HighTechBench.remove(<ItemStack>);

mods.armorplus.HighTechBench.remove(<armorplus:obsidian_chestplate>);

# mods.armorplus.UltiTechBench.addShaped(<output>, <7x7 ingredients>);

mods.armorplus.UltiTechBench.addShaped(dPickaxe,
 [[diamond, diamond, diamond, diamond, diamond, diamond, diamond],
  [null, null, null, stick, null,  null, null],
  [null, null, null, stick, null,  null, null],
  [null, null, null, stick, null,  null, null],
  [null, null, null, stick, null,  null, null],
  [null, null, null, stick, null,  null, null],
  [null, null, null, stick, null,  null, null]
  ]);
  
# mods.armorplus.UltiTechBench.remove(<ItemStack>);

mods.armorplus.UltiTechBench.remove(<armorplus:ender_dragon_helmet>);

# mods.armorplus.ChampionBench.addShaped(<output>, <9x9 ingredients>);

mods.armorplus.ChampionBench.addShaped(dPickaxe,
 [[diamond, diamond, diamond, diamond, diamond, diamond, diamond, diamond, diamond],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null],
  [null, null, null, null, stick, null, null,  null, null]
  ]);
  
# mods.armorplus.ChampionBench.remove(<ItemStack>);

mods.armorplus.ChampionBench.remove(<minecraft:stick>);

# mods.armorplus.LavaInfuser.addRecipe(<output>, <ingredient>, <exp_double>);

mods.armorplus.LavaInfuser.addRecipe(<minecraft:obsidian>, <minecraft:water_bucket>, 0.0);

# mods.armorplus.LavaInfuser.remove(<ItemStack>);

mods.armorplus.LavaInfuser.remove(<minecraft:stick>);

print("Finished Initializing 'armorplus.zs'");

is possible to get remove all piece of code 1.12.2