cool parser

parser.y

/*
 *  cool.y
 *              Parser definition for the COOL language.
 *
 */
%{
#include <iostream>
#include "cool-tree.h"
#include "stringtab.h"
#include "utilities.h"

extern char *curr_filename;


/* Locations */
#define YYLTYPE int              /* the type of locations */
#define cool_yylloc curr_lineno  /* use the curr_lineno from the lexer
			    for the location of tokens */

extern int node_lineno;          /* set before constructing a tree node
				    to whatever you want the line number
				    for the tree node to be */


#define YYLLOC_DEFAULT(Current, Rhs, N)         \
Current = Rhs[1];                             \
node_lineno = Current;


#define SET_NODELOC(Current)  \
node_lineno = Current;

/* IMPORTANT NOTE ON LINE NUMBERS
 *********************************
 * The above definitions and macros cause every terminal in your grammar to 
 * have the line number supplied by the lexer. The only task you have to
 * implement for line numbers to work correctly, is to use SET_NODELOC()
 * before constructing any constructs from non-terminals in your grammar.
 * Example: Consider you are matching on the following very restrictive 
 * (fictional) construct that matches a plus between two integer constants. 
 * (SUCH A RULE SHOULD NOT BE  PART OF YOUR PARSER):

plus_consts	: INT_CONST '+' INT_CONST 

 * where INT_CONST is a terminal for an integer constant. Now, a correct
 * action for this rule that attaches the correct line number to plus_const
 * would look like the following:

plus_consts	: INT_CONST '+' INT_CONST 
{
// Set the line number of the current non-terminal:
// ***********************************************
// You can access the line numbers of the i'th item with @i, just
// like you acess the value of the i'th exporession with $i.
//
// Here, we choose the line number of the last INT_CONST (@3) as the
// line number of the resulting expression (@$). You are free to pick
// any reasonable line as the line number of non-terminals. If you 
// omit the statement @$=..., bison has default rules for deciding which 
// line number to use. Check the manual for details if you are interested.
@$ = @3;


// Observe that we call SET_NODELOC(@3); this will set the global variable
// node_lineno to @3. Since the constructor call "plus" uses the value of 
// this global, the plus node will now have the correct line number.
SET_NODELOC(@3);

// construct the result node:
$$ = plus(int_const($1), int_const($3));
}

 */



void yyerror(char *s);        /*  defined below; called for each parse error */
extern int yylex();           /*  the entry point to the lexer  */

/************************************************************************/
/*                DONT CHANGE ANYTHING IN THIS SECTION                  */

Program ast_root;	      /* the result of the parse  */
Classes parse_results;        /* for use in semantic analysis */
int omerrs = 0;               /* number of errors in lexing and parsing */
%}

	/* A union of all the types that can be the result of parsing actions. */
	%union {
		Boolean boolean;
		Symbol symbol;
		Program program;
		Class_ class_;
		Classes classes;
		Feature feature;
		Features features;
		Formal formal;
		Formals formals;
		Case case_;
		Cases cases;
		Expression expression;
		Expressions expressions;
		char *error_msg;
	}

/* 
   Declare the terminals; a few have types for associated lexemes.
   The token ERROR is never used in the parser; thus, it is a parse
   error when the lexer returns it.

   The integer following token declaration is the numeric constant used
   to represent that token internally.  Typically, Bison generates these
   on its own, but we give explicit numbers to prevent version parity
   problems (bison 1.25 and earlier start at 258, later versions -- at
   257)
 */
%token CLASS 258 ELSE 259 FI 260 IF 261 IN 262 
%token INHERITS 263 LET 264 LOOP 265 POOL 266 THEN 267 WHILE 268
%token CASE 269 ESAC 270 OF 271 DARROW 272 NEW 273 ISVOID 274
%token <symbol>  STR_CONST 275 INT_CONST 276 
%token <boolean> BOOL_CONST 277
%token <symbol>  TYPEID 278 OBJECTID 279 
%token ASSIGN 280 NOT 281 LE 282 ERROR 283

/*  DON'T CHANGE ANYTHING ABOVE THIS LINE, OR YOUR PARSER WONT WORK       */
/**************************************************************************/

/* Complete the nonterminal list below, giving a type for the semantic
   value of each non terminal. (See section 3.6 in the bison 
   documentation for details). */

/* Declare types for the grammar's non-terminals. */
%type <program> program
%type <classes> class_list
%type <class_> class
%type <feature> feature
%type <features> feature_list
%type <feature> method
%type <feature> attr
%type <formal> formal
%type <formals> formal_list
%type <expression> expr
%type <expression> block
%type <expression> dispatch
%type <expression> static_dispatch
%type <expressions> expr_list
%type <expressions> args_list
%type <case_> branch
%type <cases> cases
%type <expression> let
%type <feature> let_attr
%type <features> rest_let_attrs


/* Precedence declarations go here. */

%right ASSIGN
%nonassoc NOT
%nonassoc  LE '<' '='
%left '+' '-'
%left '*' '/'
%nonassoc ISVOID 
%nonassoc '~' 
%nonassoc '@'
%nonassoc '.'

%%
/* 
   Save the root of the abstract syntax tree in a global variable.
 */
program	: class_list	{ @$ = @1; ast_root = program($1); }
;

class_list
: class			/* single class */
{
	$$ = single_Classes($1);
	parse_results = $$; 
}
| class_list class	/* several classes */
{ 
	$$ = append_Classes($1,single_Classes($2)); 
	parse_results = $$; 
}
;

	/* If no parent is specified, the class inherits from the Object class. */
class	
: CLASS TYPEID '{' feature_list '}' ';'
{ 
	$$ = class_($2,idtable.add_string("Object"),$4,
		stringtable.add_string(curr_filename)); 
}
| CLASS TYPEID INHERITS TYPEID '{' feature_list '}' ';'
{ 	
	$$ = class_($2,$4,$6,stringtable.add_string(curr_filename)); 
}
/* if TYPEID is invalid, consider fatal error */
| CLASS TYPEID error '{' feature_list '}' ';'
{
	yyerrok;
}
;

/* Feature list may be empty, but no empty features in list. */
feature_list
:		/* empty */
{  
	$$ = nil_Features(); 
}
| feature_list feature ';'
{
	$$ = append_Features($1, single_Features($2)); 
}
| feature_list error ';'
{
	yyclearin;
	yyerrok;
}
;

feature
: method 
{  @$ = @1; $$ = $1; }
| attr
{  @$ = @1; $$ = $1; }
;

method
: OBJECTID '(' formal_list ')' ':' TYPEID '{' expr '}'
{ 
	$$ = method($1, $3, $6, $8);
}
| OBJECTID '(' ')' ':' TYPEID '{' expr '}'
{ 
	$$ = method($1, nil_Formals(), $5, $7);
}
| error '(' formal_list ')' ':' TYPEID '{' expr '}'
{
	yyclearin;
	yyerrok;
}
| error '(' ')' ':' TYPEID '{' expr '}'
{
	yyclearin;
	yyerrok;
}
;

attr
: OBJECTID ':' TYPEID 
{
	$$ = attr($1, $3, no_expr());
}
| OBJECTID ':' TYPEID ASSIGN expr
{
 	$$ = attr($1, $3, $5);
}
| error ':' TYPEID 
{
	yyerrok;
}
| error ':' TYPEID ASSIGN expr
{
	yyerrok;
}
;

formal_list
: formal
{	
	$$ = single_Formals($1);
}
| formal_list ',' formal
{
	$$ = append_Formals($1, single_Formals($3));
}
| formal_list error formal
{
	yyclearin;
	yyerrok;
}
;

formal
: OBJECTID ':' TYPEID
{
	$$ = formal($1, $3);
}
;

expr
: OBJECTID ASSIGN expr  /* assign */
{
	$$ = assign($1, $3);
}
| OBJECTID
{
	$$ = object($1);
}
| ISVOID expr
{
	$$ = isvoid($2);
}
| NEW TYPEID
{
	$$ = new_($2);
}
| NEW error
{
	yyclearin;
	yyerrok;
}
| STR_CONST 
{
	$$ = string_const($1);
}
| INT_CONST
{
	$$ = int_const($1);
}
| BOOL_CONST
{
	$$ = bool_const($1);
}
| '(' expr ')'
{
	@$ = @2; $$ = $2;
}
| NOT expr  /* comp */
{
	$$ = comp($2);
}
| expr LE expr /* a <= b */
{
	$$ = leq($1, $3);
}
| expr '=' expr 
{ 
	$$ = eq($1, $3);
}
| expr '<' expr
{
	$$ = lt($1, $3);
}
| '~' expr
{ 
	$$ = neg($2);
}
| expr '/' expr
{
	$$ = divide($1, $3);
}
| expr '*' expr
{
	$$ = mul($1, $3);
}
| expr '-' expr
{
	$$ = sub($1, $3);
}
| expr '+' expr
{
	$$ = plus($1, $3);
}
| let 
{
	@$ = @1; $$ = $1;
}
| WHILE expr LOOP expr POOL
{
	$$ = loop($2, $4);
}
| IF expr THEN expr ELSE expr FI
{
	$$ = cond($2, $4, $6);
}
| block 
{
 	@$ = @1; $$ = $1; 
}
| CASE expr OF cases ESAC
{
	$$ = typcase($2, $4);
}
| dispatch
{
	@$ = @1; $$ = $1;
}
| static_dispatch
{
	@$ = @1; $$ = $1;
}
| WHILE expr error expr POOL
{
	yyclearin;
	yyerrok;
}
| WHILE expr LOOP expr error
{
	yyclearin;
	yyerrok;
}
| IF expr THEN expr error expr FI
{
	yyclearin;
	yyerrok;
}
| IF expr THEN expr ELSE expr error
{
	yyerrok;
}
| CASE error OF cases ESAC
{
	yyclearin;
	yyerrok;
}
;
 
dispatch
: expr '.' OBJECTID '(' args_list ')' 
{
	$$ = dispatch($1, $3, $5);
}
| expr '.' OBJECTID '(' ')' 
{
	$$ = dispatch($1, $3, nil_Expressions());
}
| OBJECTID '(' args_list ')'
{
	$$ = dispatch(object(idtable.add_string("self")), $1, $3);
}
| OBJECTID '(' ')'
{
	$$ = dispatch(object(idtable.add_string("self")), $1, nil_Expressions());
}
;

static_dispatch
: expr '@' TYPEID '.' OBJECTID '(' args_list ')'
{
	$$ = static_dispatch($1, $3, $5, $7);
}
| expr '@' TYPEID '.' OBJECTID '(' ')'
{
	$$ = static_dispatch($1, $3, $5, nil_Expressions());
}
;

args_list
: expr
{
	$$ = single_Expressions($1);
}
| args_list ',' expr
{
	$$ = append_Expressions($1, single_Expressions($3));
}
;
 

	/* let is translated into nested single expr lets */
let
: LET let_attr rest_let_attrs IN expr /* %prec '.' without this I won, but why */
{
	Features l = $3;
	Expression e = $5;
	int size = l->len();
	for (int i = size - 1; i >= 0; i--) {
		attr_class* f = (attr_class*)l->nth(i);
		e = let(f->get_name(), f->get_type_decl(), f->get_init(), e);	
	}
	
	attr_class* a = (attr_class*)($2);
	$$ = let(a->get_name(), a->get_type_decl(), a->get_init(), e);
}
;

let_attr
: OBJECTID ':' TYPEID 
{
	$$ = attr($1, $3, no_expr());
}
| OBJECTID ':' TYPEID ASSIGN expr
{
	$$ = attr($1, $3, $5);
}
| OBJECTID ':' TYPEID ASSIGN error
{
	yyclearin;
	yyerrok;
}
;

rest_let_attrs
: 
{
	$$ = nil_Features();
}
| rest_let_attrs ',' let_attr
{
	$$ = append_Features($1, single_Features($3));
}
;

cases
: branch
{
	$$ = single_Cases($1);
}
| cases branch
{
	$$ = append_Cases($1, single_Cases($2));
}
;

branch
: OBJECTID ':' TYPEID DARROW expr ';'
{
	$$ = branch($1, $3, $5);	
}
;


block: '{' expr_list '}'
{
//	$$ = $2->nth($2->len()-1);
	$$ = block($2);
}
|  '{' error '}'
{
	yyclearin;
	yyerrok;
}
;

expr_list
: expr ';'
{
	$$ = single_Expressions($1); 
}
| expr_list expr ';'
{
	$$ = append_Expressions($1, single_Expressions($2));
}
| expr_list error ';'
{
	yyclearin;
	yyerrok;
}
;

 /* end of grammar */
%%

/* This function is called automatically when Bison detects a parse error. */
void yyerror(char *s)
{
	extern int curr_lineno;

	cerr << "\"" << curr_filename << "\", line " << curr_lineno << ": " \
		<< s << " at or near ";
	print_cool_token(yychar);
	cerr << endl;
	omerrs++;

	if(omerrs>50) {fprintf(stdout, "More than 50 errors\n"); exit(1);}
}