aoc2015d1.gleam

import gleam/io
import gleam/int
import gleam/string
import gleam/result
import simplifile

fn update_floor(i: String, floor: Int) -> Int {
  case i {
    ")" -> floor - 1
    "(" -> floor + 1
    _ -> floor
  }
}

fn follow(inst: List(String), floor floor: Int) -> Int {
  case inst {
    [] -> floor
    [i, ..tl] -> follow(tl, update_floor(i, floor))
  }
}

fn find_basement(
    inst: List(String),
    floor floor: Int,
    position pos: Int
    ) -> Int {
  case inst {
    [] -> pos
    [i, ..tl] if floor >= 0 -> find_basement(tl, update_floor(i, floor), pos + 1)
    _ -> pos
  }
}

fn part1(input: String) {

  let floor = input
    |> string.to_graphemes()
    |> follow(floor: 0)
  
  io.print("Part1: ")
  io.println(int.to_string(floor))

}

fn part2(input: String) {
  let pos_basement =
    input
    |> string.to_graphemes()
    |> find_basement(floor: 0, position: 0)

  io.print("Part2: ")
  io.println(int.to_string(pos_basement))
}

pub fn main() {
  let data = simplifile.read(from: "./day01.txt") |> result.unwrap(or: "")
  part1(data)
  part2(data)
}