print-around.lisp

(ql:quickload :closer-mop)

(defclass foo ()
  ((bar :initarg :bar :initform nil :reader foo-bar)))

(defclass fuu (foo)
  ((baz :initarg :baz :initform nil :reader fuu-baz)))

(defmethod print-object ((f foo) stream)
  (print-unreadable-object (f stream :type t)))

(make-instance 'fuu :bar "barry" :baz "bazza")
;; => #<FUU >

(defmethod print-object :around ((f foo) stream)
  (let* ((slots (closer-mop:class-slots (class-of f)))
         (slot-names (mapcar #'closer-mop:slot-definition-name slots))
         (output (let ((s (make-string-output-stream)))
                   (call-next-method f s)
                   (get-output-stream-string s)))
         (last-char (aref output (- (length output) 1)))
         (new-output (subseq output 0 (- (length output) 1))))
    (write-string new-output stream)
    (format stream "~{~?~^ ~}"
            (loop for name in slot-names
               collect ":~(~A~) ~S"
               collect (list name (slot-value f name))))
    (write-char last-char stream)))

(make-instance 'fuu :bar "barry" :baz "bazza")
;; => #<FUU :bar "barry" :baz "bazza">

If you replace SB-MOP: with CLOSER-MOP:, (and add a dependency on CLOSER-MOP), this should work on almost all implementations.