init.coffee

# Your init script
#

class CommandEvent extends CustomEvent
  keyBindingAborted: false
  propagationStopped: false

  abortKeyBinding: ->
    @stopImmediatePropagation()
    @keyBindingAborted = true

  stopPropagation: ->
    @propagationStopped = true
    super

  stopImmediatePropagation: ->
    @propagationStopped = true
    super

atom.keymaps.dispatchCommandEvent = (command, target, keyboardEvent) ->
  # Here we use prototype chain injection to add CommandEvent methods to this
  # custom event to support aborting key bindings and simulated bubbling for
  # detached targets.
  [commandHead, commandTile] = command.split '|'

  commandEvent = new CustomEvent(commandHead, bubbles: true, cancelable: true)
  commandEvent.__proto__ = CommandEvent::
  commandEvent.originalEvent = keyboardEvent
  commandEvent.params = commandTile

  if document.contains(target)
    target.dispatchEvent(commandEvent)
  else
    @simulateBubblingOnDetachedTarget(target, commandEvent)

  {keyBindingAborted} = commandEvent
  keyboardEvent.preventDefault() unless keyBindingAborted
  not keyBindingAborted