Скрипт для запуска трансляции с камеры и микрофона в VLC. Диагностика - это фестиваль! Винтовка - это праздник!

vlc-dshow-stream.cmd

:: piv@devmem.ru, 2021. Exclusive for DONM IT Telegram Chat.

:: !!! Сохранять в кодировке OEM 866 (она же CP 866) !!!
:: Запускать от имени админа, если не меняете путь сохранения локального файла

@echo off

:: DO NOT MODIFY THIS SECTION
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
set "DATESTAMP=%YYYY%%MM%%DD%" & set "TIMESTAMP=%HH%%Min%%Sec%"
set "FULLSTAMP=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
:: DO NOT MODIFY THIS SECTION


:: ===== CHANGE THESE VARIABLES =====
set CAMERA="HP HD Camera"
set MIC="Внутренний микрофон (Conexant ISST Audio)"
set SCHOOL="1799"
set AUD="D10-31"
set LOCAL_FILE="C:\\%SCHOOL%_%AUD%_%FULLSTAMP%.ps"
:: ===== CHANGE THESE VARIABLES =====


:: Kill all running VLC processes
taskkill /IM vlc.exe /F

:: Start VLC
start "" "C:\Program Files\VideoLAN\VLC\vlc.exe" dshow:// --dshow-vdev=%CAMERA% --dshow-adev=%MIC% --dshow-caching=300 --sout=#transcode{vcodec=mp4v,fps=3,scale=автоматически,width=640,height=480,acodec=wma2,ab=256,channels=1,samplerate=22050,scodec=none}:duplicate{dst=http{mux=asf,dst=:8899/},dst=file{dst=%LOCAL_FILE%,no-overwrite}}

exit

Как этим пользоваться?

1. Скачать, установить и запустить Notepad++
2. Выбрать в меню Кодировки -> Кодировки -> Кириллица - > OEM 866
3. Скопировать и вставить код скрипта
4. Отредактировать переменные в блоке CHANGE THESE VARIABLES. Путь к локальному файлу должен содержать двойные слеши.
5. Сохранить файл с любым именем и расширением cmd, например vlc-dshow-stream.cmd (найти соответствующий тип файла в списке или выбрать All types (*.*))