README.md

Converting Quotes to Smart Quotes workflow

smart-quotes.awk can be used with awk to convert html file contents' quotes to smart quotes ("" -> “” and '' -> ‘’).

First run the script and create a new file with the output.

awk -f ~/Development/marxists.org/smart-quotes.awk input.htm > output.htm

Then run a difftool and check the output. I like to run colordiff and pipe it to less with a pattern for highlighting the characters we just attempted to edit.

colordiff -u input.htm output.htm | less -R --pattern="“|”|‘|’"

smart-quotes.aqk

function smartquote (char, prevchar, open) {
        # print smart quotes depending on the previous character
        # otherwise just print the character as-is

        # prev char is a space
        if (char == "'") {
          if (open[0] == 1) {
            printf("’");
            open[0] = 0;
          } else if (prevchar == " ") {
            printf("‘");
            open[0] = 1;
          } else {
            printf("’");
          }
        } else if (char == "\"") {
          if (open[1] == 1) {
            printf("”");
            open[1] = 0;
          } else {
            printf("“");
            open[1] = 1;
          }
        } else {
          printf("%c", char);
        }
}

BEGIN {
  htmltag = 0;
}

{
        # for each line, scan one letter at a time:

        linelen = length($0);
        open[0] = 0;
        open[1] = 0;

        prev = "\n";

        for (i = 1; i <= linelen; i++) {
                char = substr($0, i, 1);

                if (char == "<") {
                        htmltag = 1;
                }

                if (htmltag == 1) {
                        printf("%c", char);
                }
                else {
                        smartquote(char, prev, open);
                        prev = char;
                }

                if (char == ">") {
                        htmltag = 0;
                }
        }

        # add trailing newline at end of each line
        printf ("\n");
}