Mura CMS : Session Variable Example

muraSessionVars.cfm

<cfscript>
	public any function onSiteRequestStart($) {
		param name='session.customsession' default=getDefaultCustomSessionSettings();

		// you could use whatever trigger you want to set your session var(s), but i'm just using something simple for this example
		if ( IsDefined('url.somekey') ) {
			lock scope='session' type='exclusive' timeout=10 {
				session.customsession = {
					somekey = url.somekey
					, dateinitalized = Now()
					, inited = true
				}
			}
		}
	}

	public void function onGlobalSessionStart($) {
		WriteLog(text='custom session started', type='information', application=true, file='customsession');
	}


	public void function onGlobalSessionEnd($) {
		WriteLog(text='custom session expired', type='information', application=true, file='customsession');
	}

	public void function onSiteSessionEnd($) {
		onGlobalSessionEnd(argumentCollection=arguments);
	}

	private any function getDefaultCustomSessionSettings() {
		return {
			somekey = ''
			, dateinitalized = ''
			, inited = false
		};
	}
</cfscript>