Erlang module alias generator

.gitignore

ebin/*.beam

modalias.app

{application, modalias,
 [{vsn,          "1.0"},
  {modules,      [modalias]},
  {applications, [stdlib, kernel, sasl]}]
}.

modalias.erl

-module(modalias).
-export([new/2]).

new(Origin, Alias) ->
        Exports = lists:filter(fun ({module_info, _}) -> false;
                                (_) -> true end, Origin:module_info(exports)),
        Abstract = [
                {attribute, 1, module, Alias},
                {attribute, 2, export, Exports}
        ]
        ++ lists:map(fun ({FunName, Arity}) ->
                                alias_fun(Origin, FunName, Arity)
                        end, Exports),

        {ok, Alias, AliasBin} = compile:forms(Abstract),
        {module, Alias} = code:load_binary(Alias, "/dev/null", AliasBin),

        {ok, Alias}.

%% @doc Create abstract form of alias function
alias_fun(Origin, FunName, Arity) ->
        ArgList = gen_arglist(Arity),
        {function, 3, FunName, Arity, [
                {clause, 3, ArgList, [],
                        [{call, 4,
                                {remote, 4, {atom, 4, Origin}, {atom, 4, FunName}},
                                ArgList
                        }]
                }]
        }.

gen_arglist(Arity) ->
        [ {var, 3, list_to_atom("Arg" ++ integer_to_list(N))} || N <- lists:seq(1, Arity)].