Jenkins pipeline that demonstrates how to abort previous pull request build when new changes are pushed

README.md

Abort previous pull request build when new changes pushed with ghprb jenkins plugin.

Changes:

• abort the old build with the new one that starts building changes for the same pull request
• build with higher build number will abort the build with lower build number

Credits to:

• https://medium.com/@vedranvucetic/run-only-last-triggered-job-for-branch-in-descriptive-jenkins-pipeline-a07bb84ae075
• https://stackoverflow.com/a/48956042/818899

Jenkinsfile

@NonCPS
def cancelPreviousBuilds() {
    def jobName = env.JOB_NAME
    def buildNumber = env.BUILD_NUMBER.toInteger()
    def ghPrId = env.ghprbPullId.toInteger()

    /* Get job name */
    def currentJob = Jenkins.instance.getItemByFullName(jobName)

    /* Iterating over the builds for specific job */
    for (def build : currentJob.builds) {
        def listener = build.getListener()
        def ghprbPullId = build.getEnvironment(listener).get('ghprbPullId').toInteger()

        def exec = build.getExecutor()
        /* If there is a build that is currently running and it's not current build */
        if (build.isBuilding() && build.number.toInteger() < buildNumber && exec != null && ghprbPullId == ghPrId) {
            /* Then stop it */
            exec.interrupt(
                    Result.ABORTED,
                    new CauseOfInterruption.UserInterruption("Aborted by #${currentBuild.number}")
                )
            println("Aborted previously running build #${build.number}")
        }
    }
}

pipeline {
    agent any
    stages {
        stage('Init') {
            agent { label 'master' }
            steps {
                script {
                    cancelPreviousBuilds()
                }
            }  
        }
        stage('Test') {
            agent { label 'agent' }
            steps {
              //...
            }
        }
    }
}

Thanks for this! My working version is below. I removed the commit id check as my project only builds on branches and not PRs, therefore, ghprbPullId seemed to be null.

I also needed to approve a bunch of methods to be executed in the script, simply check if your log has something like "administrator needs to approve blah blah", follow that link and click approve

@NonCPS
def cancelPreviousBuilds() {
    def jobName = env.JOB_NAME
    def buildNumber = env.BUILD_NUMBER.toInteger()

    /* Get job name */
    def currentJob = Jenkins.instance.getItemByFullName(jobName)

    /* Iterating over the builds for specific job */
    for (def build : currentJob.builds) {
        def listener = build.getListener()
        def exec = build.getExecutor()
        /* If there is a build that is currently running and it's not current build */
        if (build.isBuilding() && build.number.toInteger() < buildNumber && exec != null) {
            /* Then stop it */
            exec.interrupt(
                    Result.ABORTED,
                    new CauseOfInterruption.UserInterruption("Aborted by #${currentBuild.number}")
                )
            println("Aborted previously running build #${build.number}")
        }
    }
}