task.cue

{
    PendingTask | EndedTask | WaitingTask | RecurringParrentTask | RecurringChildTask
    ...
}

Task :: {
    status: Status
    uuid: Uuid
    entry: Date
    description: string

    start?: Date

    due?: Date
    until?: Date

    modified: Date
    scheduled?: Date

    project?: string
    priority?: Priority
    depends?: string
    tags: [...Word]
    annotations?: [...Annotation]
}

Active :: {
    end?: _|_
    wait?: _|_
}

NonRecurring :: {
    recur?: _|_
    mask?: _|_
    imask?: _|_
    parrent?: _|_
}

PendingTask :: {
    Task

    Active
    NonRecurring
}

EndedTask :: {
    Task
    status: "deleted" | "completed"
    end: Date

    wait?: _|_
    NonRecurring
}

WaitingTask :: {
    Task
    status: "waiting"
    wait: Date

    end?: _|_
    NonRecurring
}

RecurringTask :: {
    Task
    status: "recurring"
    recur: Duration

    Active
}

RecurringParrentTask :: {
    RecurringTask
    due: Date
    mask: Mask

    imask?: _|_
    parrent?: _|_
}

RecurringChildTask :: {
    RecurringTask
    imask: int
    parrent: Uuid

    mask?: _|_
}

Annotation :: {
    entry: Date
    description: string
}

Status :: "pending" | "deleted" | "completed" | "waiting" | "recurring"
Mask :: =~ "[-+XW]{4}"
Word :: =~ "[^ ]+"
Priority :: "H" | "M" | "L"
Uuid :: =~ "[0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12}"
Date :: =~ "[0-9]{8}T[0-9]{6}Z"
Duration :: string