spirv-cross

PKGBUILD

# Maintainer: Daniel Bermond <dbermond@archlinux.org>


pkgname=spirv-cross
pkgver=1.3.216.0
pkgrel=1
epoch=1
pkgdesc='A tool and library for parsing and converting SPIR-V to other shader languages'
arch=('x86_64')
url='https://github.com/KhronosGroup/SPIRV-Cross/'
license=('Apache')
depends=('gcc-libs' )
makedepends=('git' 'cmake' 'python' 'glslang' 'spirv-headers' 'spirv-tools')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/KhronosGroup/SPIRV-Cross/archive/refs/tags/sdk-${pkgver}.tar.gz"
)
sha256sums=('dd66ce2f9e6d3b9b8055662ac25172fa5559603f2f23c1a178c74f1602de8732')

build() {
    cd $srcdir
    mkdir build-SPIRV-Cross
    # NOTE: test suite fails when using 'None' build type
    local -a _common_opts=('-DCMAKE_BUILD_TYPE:STRING=Release' '-Wno-dev')

    export CFLAGS+=' -ffat-lto-objects'
    export CXXFLAGS+=' -ffat-lto-objects'
    # spirv-cross
    cmake -B build-SPIRV-Cross -S SPIRV-Cross-sdk-${pkgver} \
        "${_common_opts[@]}" \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DSPIRV_CROSS_FORCE_PIC:BOOL='ON' \
        -DSPIRV_CROSS_SHARED:BOOL='ON'
    make -C build-SPIRV-Cross
}

check() {
    make -C build-SPIRV-Cross test
}

package() {
    make -C build-SPIRV-Cross DESTDIR="$pkgdir" install
}