composite views blog pot code

table_row_view2.coffee

class Example.Views.TableRowView extends Backbone.View
  
  tagName: "tr"
  
  attributes: ->
    id: "row_#{@model.id}"
    
  constructor: (options) ->
    super
    @parentView = options.parentView
    @parentView.on "rendered", =>
      @setElement @parentView.$("#row_#{@model.id}")
      @render()
      
  toHtml: ->
    @$el.clone().wrap("<p>").parent().html()

  events:
    "click td": "clicked"
    
  clicked: ->
    alert "Way to go, you clicked a cell!"
    
  render: ->
    @$el.html JST["table_row_view_template"] @

table_row_view_no_events.coffee

class Example.Views.TableRowView extends Backbone.View
    
  render: ->
    @$el.html JST["table_row_view_template"] @

table_row_view_template.haml

%tr
  %td= @model.get("first_name")
  %td= @model.get("last_name")

table_row_view_with_events.coffee

class Example.Views.TableRowView extends Backbone.View
  
  events:
    "click td": "clicked"
    
  clicked: ->
    alert "Way to go, you clicked a cell!"
    
  render: ->
    @$el.html JST["table_row_view_template"] @

table_view.coffee

class Example.Views.TableView extends Backbone.View
  
  render: ->
    @$el.html JST["table_view_template"] @
    
  tableRow: (person) ->
    tableRowView = new Example.Views.TableRowView(model: person)
    tableRowView.render()
    tableRowView.$el.html()

table_view2.coffee

class Example.Views.TableView extends Backbone.View
  
  render: ->
    @$el.html JST["table_view_template"] @
    for person in @collection.models
      tableRowView = new Example.Views.TableRowView(model: person, el: @$("#row_#{person.id}"))
      tableRowView.render()
    
  tableRow: (person) ->
    "<tr id='row_#{person.id}'></tr>"

table_view3.coffee

class Example.Views.TableView extends Backbone.View
  
  render: ->
    @$el.html JST["table_view_template"] @
    @trigger "rendered"
    
  tableRow: (person) ->
    new Example.Views.TableRowView(parentView: @, model: person).toHtml()
    

table_view_template.haml

%table.table-bordered
  %thead
    %tr
      %th First Name
      %th Last Name
  %tbody
    - for person in @collection.models
      = @tableRow(person)