server.clj

(ns monolith.server
  (:require [org.httpkit.server :as http]
            [clojure.tools.namespace.repl :as tn]
            [ring.middleware.json :refer [wrap-json-body wrap-json-response]]
            [ring.middleware.defaults :refer [wrap-defaults api-defaults]]
            [monolith.env :as env]
            [monolith.routes :refer [routes]]
            [monolith.http :refer [response]]
            [monolith.utils :refer [throw+]]
            [monolith.logic.tokens :as tokens]))

(defn wrap-exceptions [handler]
  (fn [request]
    (try
      (handler request)
      (catch Exception e
        (let [{:keys [status]} (ex-data e)
              message (.getMessage e)]
          (response (or status 500) {:message message}))))))

(def app
  (-> routes
      (wrap-exceptions)
      (wrap-defaults api-defaults)
      (wrap-json-body {:keywords? true})
      (wrap-json-response)))

(defonce server (atom nil))

(defn start []
  (let [opts {:port env/port}]
    (reset! server (http/run-server #'app opts))))

(defn stop []
  (when @server
    (@server :timeout 100)
    (reset! server nil)))

(defn restart []
  (stop)
  (tn/refresh :after 'monolith.core/start))