switch.clj

(ns switch
  (:require [clojure.pprint :as pprint]))

(defn project-clj-map [filename]
  (->> (slurp filename)
       (read-string)
       (drop 1)
       (partition 2)
       (map vec)
       (into {})))

(defn lein-deps [filename]
  (let [project-clj (project-clj-map filename)]
    (get project-clj :dependencies)))

(defn edn-dep [lein-dep]
  (let [[id version] lein-dep]
    {id {:mvn/version version}}))

(defn edn-deps [lein-deps]
  (let [deps (into {} (map edn-dep lein-deps))]
    {:deps deps}))

(defn pprint-write [out-file m]
  (with-open [w (clojure.java.io/writer out-file)]
    (binding [*out* w]
      (pprint/write m))))

(defn spit-edn-deps []
  (->> (lein-deps "project.clj")
       (edn-deps)
       (pprint-write "deps.edn")))


(spit-edn-deps)

Nice

Then probably:

mkdir src
mv switch.cljs src
clj -m switch

This is so hacky but unlike it. Maybe trunk it into a lein plugin ?

s/unlike/I like

Yeah I should make it a proper lein plugin, lein deps.edn or something like that?

If you change this:

(defn -main []
  (spit-edn-deps))

into this

(spit-edn-deps)

you can run it with

curl https://gist.githubusercontent.com/swlkr/[...]/raw/[...]/switch.clj | clj -

or download the file first and run clj switch.clj

I just changed it, that's incredible

that is, indeed, amazing. Simple yet effective. How cool.

@ordnungswidrig @swlkr I'd go so far and say leiningen core should be shipping this functionality.

FYI with a couple of minor changes I made this script work with babaksha https://github.com/borkdude/babashka which makes it run reaaally fast

#!/usr/bin/env bb

(defn project-clj-map [filename]
  (->> (slurp filename)
       (read-string)
       (drop 1)
       (partition 2)
       (map vec)
       (into {})))

(defn lein-deps [filename]
  (let [project-clj (project-clj-map filename)]
    (get project-clj :dependencies)))

(defn edn-dep [lein-dep]
  (let [[id version] lein-dep]
    {id {:mvn/version version}}))

(defn edn-deps [lein-deps]
  (let [deps (into {} (map edn-dep lein-deps))]
    {:deps deps}))

(defn pprint-write [out-file m]
  (with-open [w (clojure.java.io/writer out-file)]
    (binding [*out* w]
      (clojure.pprint/pprint m))))

(defn spit-edn-deps []
  (->> (lein-deps "project.clj")
       (edn-deps)
       (pprint-write "deps.edn")))


(spit-edn-deps)

nice! babashka is incredible