showSbtDependencies Jenkins Pipeline Step

showSbtDependencies.groovy

#!/usr/bin/groovy

/**
 * Extract project versions from all SBT POMs and publish them as summary badge.
 *
 * Requires Badge and Pipeline Utility Step plugins.
 */

def call() {
    // Clear out old badge if any
    removeBadges id: 'sbt-dependencies'

    // Collect dependencies
    def poms = findFiles glob: '**/target/scala-*/*.pom'
    def dependencies = poms.collect { file ->
        def pom = readMavenPom file: file.path
        // We do not use artifactId here because it already includes the scala version
        [group: pom.groupId, name: pom.name.toLowerCase(), version: pom.version]
    }

    // Render badge
    if (!dependencies.isEmpty()) {
        def badge = createSummary icon: 'package.png', id: 'sbt-dependencies',
                text: '<p>SBT dependencies published by this build:</p>\n'
        badge.appendText('<ul>\n')
        for (dependency in dependencies) {
            badge.appendText("<li><code>\"${dependency.group}\" %% \"${dependency.name}\" % \"${dependency.version}\"</code></li>\n")
        }
        badge.appendText('</ul>\n')
    }

    // Make collected dependencies available to caller
    return dependencies
}