0001-gnucash-5.0.patch

From b13357ff897c4af6d265fde76c2091dd91c832f4 Mon Sep 17 00:00:00 2001
From: Sebastian Wiesner <sebastian@swsnr.de>
Date: Wed, 5 Apr 2023 19:10:37 +0200
Subject: [PATCH] gnucash 5.0

Set CMAKE_BUIL_TYPE=None per CMake packaging guidelines, and use ninja
to build.
---
 trunk/PKGBUILD | 42 +++++++++++++++++++++++-------------------
 1 file changed, 23 insertions(+), 19 deletions(-)

diff --git a/trunk/PKGBUILD b/trunk/PKGBUILD
index c5dc05b..3a3c018 100644
--- a/trunk/PKGBUILD
+++ b/trunk/PKGBUILD
@@ -4,43 +4,47 @@
 # Contributor: Mark Schneider <queueRAM@gmail.com>
 
 pkgname=gnucash
-pkgver=4.13
-pkgrel=2
+pkgver=5.0
+pkgrel=1
 pkgdesc='Personal and small-business financial-accounting application'
 arch=(x86_64)
 url='https://gnucash.org/'
 license=(GPL)
 depends=(aqbanking gwenhywfar boost-libs guile libdbi webkit2gtk libofx)
-makedepends=(boost cmake gtest libdbi-drivers mariadb-libs postgresql-libs swig python)
+makedepends=(boost cmake ninja gtest libdbi-drivers mariadb-libs postgresql-libs swig python)
 optdepends=('gnucash-docs: documentation'
-            'libdbi-drivers: open and save data into SQL database'
-            'perl-date-manip: stock information lookups'
-            'perl-finance-quote: stock information lookups')
+  'libdbi-drivers: open and save data into SQL database'
+  'perl-date-manip: stock information lookups'
+  'perl-finance-quote: stock information lookups')
 options=(!emptydirs)
-source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
-sha256sums=('401a158086635ea17fbb145325558537289aa1d24d022f7c3317e12f3dabd8e7')
+source=("https://github.com/Gnucash/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('66dd5e32829cb6d8dd9a7e017a894583c7579932d13c4fe024329d9c6cfe956d')
 
 build() {
-  cd $pkgname-$pkgver
+  cd "$srcdir"
 
   # Do not treat warnings as errors
-  sed -e 's|-Werror||g' -i CMakeLists.txt
+  sed -e 's|-Werror||g' -i "$pkgname-$pkgver/CMakeLists.txt"
 
-  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
-        -DWITH_PYTHON=ON \
-        -DCOMPILE_GSCHEMAS=OFF
-  make
+  cmake -GNinja -B build -S "$pkgname-$pkgver" \
+    -DCMAKE_BUILD_TYPE='None' \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DWITH_PYTHON=ON \
+    -DCOMPILE_GSCHEMAS=OFF \
+    -Wno-dev
+  cmake --build build
 }
 
 check() {
-  cd $pkgname-$pkgver
-  make -k check || : # 2 tests failed
+  cd "$srcdir/build"
+  CTEST_OUTPUT_ON_FAILURE=on ninja check || : # 2 tests failed
 }
 
 package() {
-  cd $pkgname-$pkgver
-  make DESTDIR="$pkgdir" install
+  cd "$srcdir"
+
+  DESTDIR="${pkgdir}" cmake --install build
 
   # Delete the gnucash-valgrind executable because the source files
   # are not included with the package and the executable is hardlinked
-- 
2.40.0