emacsclient のラッパスクリプトemacs.exe プロセスの有無と引数の有無に応じて startup_emacs.exe、startup_emacsclient.exe を起動。

emacsclientw.vbs

'
' C:\gnupack_devel\emacsclientw.vbs
'
Set objShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_Process")
Dim emacsProcess
emacsProcess = null
For Each objItem in colItems
    If InStr(objItem.CommandLine, "emacs.exe") Then
        Set emacsProcess = objItem
    End If
Next

If WScript.Arguments.Count >= 1 Then
  ReDim args(WScript.Arguments.Count-1)
  For i = 0 To WScript.Arguments.Count-1
    args(i) = WScript.Arguments(i)
  Next
  strArgs = """" & Join(args, """ """) & """"

  If IsNull(emacsProcess) Then
    objShell.Run("""" & fso.GetParentFolderName(WScript.ScriptFullName) & "\startup_emacs.exe"" " & strArgs)
  Else
    objShell.Run("""" & fso.GetParentFolderName(WScript.ScriptFullName) & "\startup_emacsclient.exe"" " & strArgs)
  End If
Else
  If IsNull(emacsProcess) Then
    objShell.Run("""" & fso.GetParentFolderName(WScript.ScriptFullName) & "\startup_emacs.exe""")
  Else
    objShell.AppActivate("emacs ")
  End If
End If

gnupack用にstartup_emacs.exeを使うようにした。
ファイルが複数渡された場合、全部開くようにした。

プロセスID指定で「objShell.AppActivate emacsProcess.ProcessID」してもアクティブにならなかった。。
emacsウィンドウが最小化状態だとAppActivateしても前面に出てこない。。