DBFluteのload-data-reverseで出力したExcelを１テーブル１ファイルに分解するGroovyスクリプト

TakeApart.groovy

@Grab('org.apache.poi:poi:3.9')
import org.apache.poi.hssf.usermodel.*

def config = [
    reverseDir  : 'output/doc/data',
    dataDir     : 'playsql/data/ut/xls',
    tableNameMap: 'tableNameMap.dataprop',
    ignoreTable : [
        'ignore_table_name',
    ],
]

new File(config.reverseDir).eachFileMatch(~/.*\.xls/) {
    f ->
    def numbering = (f.name =~ /load-data-(\d+)\b/)[0][1]

    f.withInputStream {
        fin ->
        def book = new HSSFWorkbook(fin)
        def numOfSheets = book.numberOfSheets
        book.sheets.eachWithIndex {
            sheet, i ->
            println i + ' ' + sheet.sheetName
            if (config.ignoreTable.find { it == sheet.sheetName }) {
                println '    ... skip'
                return
            }

            f.withInputStream {
                pin ->
                def parted = new HSSFWorkbook(pin)
                parted.cloneSheet(i)
                for (s in numOfSheets - 1..0) {
                    parted.removeSheetAt(s)
                }
                parted.setSheetName(0, sheet.sheetName)
                new File("${config.dataDir}/${numbering}-${i}-${sheet.sheetName}.xls").withOutputStream { parted.write(it) }
            }
        }
    }
}

new AntBuilder().copy(file: "${config.reverseDir}/${config.tableNameMap}", tofile: "${config.dataDir}/${config.tableNameMap}")