arch-aur-pulseview-0.3.0-1-PKGBUILD

# Maintainer: Thomas Krug <t.krug@elektronenpumpe.de>
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>

pkgname=pulseview
pkgver=0.3.0
pkgrel=1
pkgdesc="A Qt based logic analyzer GUI for sigrok."
arch=('i686' 'x86_64')
url="http://sigrok.org/wiki/Main_Page"
license=('GPL3')
depends=('libsigrok' 'libsigrokdecode' 'qt5-base' 'qt5-svg' 'boost-libs')
makedepends=('cmake' 'boost')
source=("http://sigrok.org/download/source/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        'pulseview.desktop'
        'pulseview-0.3.0-0.patch::http://sigrok.org/gitweb/?p=pulseview.git;a=patch;h=c28fa62bc89656ba3b1b01011a45e941d6c7d42a'
        'pulseview-0.3.0-1.patch::http://sigrok.org/gitweb/?p=pulseview.git;a=patch;h=5d6ae8a26c8d86531d0d85d2fefc67d617c73f56')
md5sums=('2cd76988cbf2a74b383e30de27744016'
         'f816b4aff1ddf5683d5df94e69576ec7'
         '282e2c3d5a3940e8dd128f8dc0095f03'
         'f34dcb25c5c84b3193827dc883876905')
install=${pkgname}.install

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 < ../pulseview-0.3.0-0.patch
  patch -Np1 < ../pulseview-0.3.0-1.patch
}

build() {
  cd "$srcdir/${pkgname}-${pkgver}"

  cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr .
  make
}

package() {
  cd "$srcdir/${pkgname}-${pkgver}"

  make DESTDIR="$pkgdir" PREFIX=/usr install
  install -Dm644 ../pulseview.desktop "$pkgdir/usr/share/applications/pulseview.desktop"
}

# vim:set ts=2 sw=2 et: