node-require-snoop.coffee

# This will collect module paths and versions for all
#   modules loaded in the process. Should be called
#   before any other require()s
versionCache = {}
(->
  Path = require 'path'
  Module = require('module')

  Object.keys(Module._extensions).forEach (ext) ->
    # Leave the JSON handler alone
    return if ext is '.json'

    origRequire = Module._extensions[ext]
    Module._extensions[ext] = (info, filepath) ->
      packageInfo = null
      modulepath = Path.dirname filepath
      basepath = Path.join __dirname, 'node_modules'

      while not packageInfo? and modulepath?
        try
          packageInfo = require Path.join(modulepath, 'package.json')
        catch ex
          modulepath = Path.join modulepath, '..'
          if modulepath is basepath or modulepath.length <= basepath.length
            # We're at the top level or off the reservation, so stop
            modulepath = null 

      if packageInfo?
        versionCache[modulepath] = packageInfo.version

      console.log 'REQUIRE [' + ext + ']', modulepath, packageInfo?

      return origRequire.apply Module, arguments
)()