SQL SERVER: List tables with ANSI PADDING off

FindAllTablesWithColumnsAnsiPaddingOff.sql

IF OBJECT_ID('tempdb..#tbl') IS NOT NULL DROP TABLE #tbl

CREATE TABLE #tbl (
	[DBName] sysname,
	[TableName] sysname,
	[ColumnName] sysname,
	[DataType] sysname
)

EXEC master.dbo.sp_MSforeachdb @command1 = N'
	USE [?]
	INSERT INTO #tbl (
		[DBName],
		[TableName],
		[ColumnName],
		[DataType]
	)
	SELECT ''?'',
		   [t].[name] AS [TableName],
		   [c].[name] AS [ColumnName],
		   [typ].[name] AS [DataType]
	FROM   [sys].[columns] AS [c]
		   INNER JOIN [sys].[tables] AS [t] ON [c].object_id = [t].object_id
		   INNER JOIN [sys].[types] AS [typ] ON [c].[system_type_id] = [typ].[system_type_id]
												AND [c].[user_type_id] = [typ].[user_type_id]
	WHERE  [t].[type] = N''U''
		   AND [c].[is_ansi_padded] = 0
		   AND ([typ].[name] LIKE ''%char''
				OR [typ].[name] LIKE ''%binary'');

'

SELECT t.DBName,
	   t.TableName,
	   t.ColumnName,
	   t.DataType 
FROM #tbl t

ListTablesWithAnsiPaddingOff.sql

SELECT [t].[name] AS [TableName],
	   [c].[name] AS [ColumnName],
	   [typ].[name] AS [DataType]
FROM   [sys].[columns] AS [c]
INNER JOIN [sys].[tables] AS [t] ON [c].object_id = [t].object_id
INNER JOIN [sys].[types] AS [typ] ON [c].[system_type_id] = [typ].[system_type_id] AND [c].[user_type_id] = [typ].[user_type_id]
WHERE  [t].[type] = N'U'
	AND [c].[is_ansi_padded] = 0
	AND ([typ].[name] LIKE '%char'
		OR [typ].[name] LIKE '%binary');