Skip to content

Instantly share code, notes, and snippets.

@tchebb

tchebb/PKGBUILD

Last active Aug 29, 2015
Embed
What would you like to do?
Updated PKGBUILD for abootimg-git
# Maintainer: Benoit Favre <benoit.favre@gmail.com>
# Contributor: Thomas Hebb <tommyhebb@gmail.com>
pkgname=abootimg-git
pkgver=0.6.r4.g7e127fe
pkgrel=1
pkgdesc="A tool to read/write/update android boot images"
arch=('i686' 'x86_64' 'arm' 'armv7h')
url="http://gitorious.org/ac100/abootimg"
license=('GPL')
depends=('util-linux' 'cpio')
makedepends=('git')
provides=('abootimg')
source=('git://gitorious.org/ac100/abootimg.git')
sha256sums=('SKIP')
pkgver() {
cd "abootimg"
git describe --long --tags | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/abootimg"
make
gzip debian/abootimg.1
}
package() {
cd "${srcdir}/abootimg"
install -d "$pkgdir/usr/bin" "$pkgdir/usr/share/man/man1/"
install -t "$pkgdir/usr/bin" abootimg abootimg-pack-initrd abootimg-unpack-initrd
install -t "$pkgdir/usr/share/man/man1/" debian/abootimg.1.gz
}
# vim:set ts=2 sw=2 et:
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment