assert_match.ex

  @doc """
  Asserts based on pattern matching.

  Example: check if collection contains element that matches the pattern

      assert_match %{body: "lorem"} in messages
      assert_match %{id: ^id} in response["users"]
  """
  defmacro assert_match({:in, _, [left, right]} = assertion) do
    code = Macro.escape(assertion)
    left = Macro.expand(left, __CALLER__)
    pins = collect_pins_from_pattern(left)

    quote do
      right = unquote(right)
      assert Enum.any?(right, fn
        unquote(left) -> true
        _ -> false
      end),
        right: right,
        expr: unquote(code),
        message: "match (=) in collection failed" <> ExUnit.Assertions.__pins__(unquote(pins))
    end
  end

  # stolen from ExUnit
  defp collect_pins_from_pattern(expr) do
    {_, pins} =
      Macro.prewalk(expr, [], fn
        {:^, _, [{name, _, _} = var]}, acc ->
          {:ok, [{name, var} | acc]}
        form, acc ->
          {form, acc}
      end)
    Enum.uniq_by(pins, &elem(&1, 0))
  end