justfile for continuous testing and tcr

justfile for tdd using Maven Daemon (mvnd)

# justfile (see https://just.systems/man/en/ for docs on "just")
goal +MESSAGE:
    git pull --rebase
    git commit --allow-empty -m "Goal: {{MESSAGE}}"
    git push

commit:
    @git add . 
    -@git commit -am "wip"

# requires Maven Daemon: install with SDKMAN: 'sdk install mvnd'
# more docs at: https://github.com/apache/maven-mvnd
test:
    clear
    @mvnd test

test-commit:
    just test 
    just commit

# trying this out (use test-commit for now)
test-mob-next:
    just test
    mob next

integrate:
    git pull --rebase
    just test 
    just commit
    git push
    
# requires watchexec: install with Homebrew: 'brew install watchexec'
# more docs at: https://github.com/watchexec/watchexec#install
# LOCAL TDD: if tests pass, then does git commit
tdd:
    watchexec -e java just test-commit

# trying this out using `mob` instead of git
tdd-mob:
    watchexec -e java just test-mob-next

ci:
    watchexec -e java just integrate

revert:
    @git reset --hard &> /dev/null
    @git clean -df &> /dev/null
    @echo -e "\033[0;31m=== REVERTED ==="