GMSH PKGBUILD

PKGBUILD

# Contributor: Runar Tenfjord <runar.tenfjord@gmail.com>
_realname=gmsh
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=2.8.5
pkgrel=1
pkgdesc="An automatic 3D finite element mesh generator with pre and post-processing facilities."
arch=('i686' 'x86_64')
url="http://www.geuz.org/gmsh/"
license=('custom')
depends=(
    "${MINGW_PACKAGE_PREFIX}-fltk"
    "${MINGW_PACKAGE_PREFIX}-cairo"
    "${MINGW_PACKAGE_PREFIX}-openblas"
)
makedepends=(
    "${MINGW_PACKAGE_PREFIX}-cmake"
    "${MINGW_PACKAGE_PREFIX}-swig"
    "${MINGW_PACKAGE_PREFIX}-gcc"
)
optdepends=(
    "${MINGW_PACKAGE_PREFIX}-python2"
    "${MINGW_PACKAGE_PREFIX}-python3"
)
options=(!emptydirs)
source=("${url}src/${_realname}-${pkgver}-source.tgz")
md5sums=('6fd196a4ee31d3adf53ac95e4a2d51ba')

build() {
   cd "${srcdir}/${_realname}-${pkgver}-source"

   # Help links to local doc (package gmsh-docs)
   sed -e "s|http://geuz.org/gmsh/doc/texinfo/|file:///usr/share/doc/gmsh/gmsh.html|" \
       -i Fltk/graphicWindow.cpp
   sed -e "s|http://geuz.org/gmsh/doc/|/usr/share/licenses/gmsh/|" \
       -i Fltk/helpWindow.cpp

   mkdir -p build
   cd build
   
   ${MINGW_PREFIX}/bin/cmake \
    -G"MSYS Makefiles" \
    -DCMAKE_INSTALL_PREFIX=${pkgdir}${MINGW_PREFIX} \
    -DCMAKE_BUILD_TYPE=RELEASE \
    -DCMAKE_RC_FLAGS=--use-temp-file \
    -DENABLE_BUILD_SHARED=ON \
    -DENABLE_OCC=0 \
    ..
   
   make
}

package() {
   cd "${srcdir}/${_realname}-${pkgver}-source/build"
   make DESTDIR=${pkgdir}${MINGW_PREFIX} install
   install -D -m644 "${pkgdir}${MINGW_PREFIX}/bin/onelab.py" \
        "${pkgdir}${MINGW_PREFIX}/lib/python2.7/site-packages/onelab.py"
   install -D -m644 "${pkgdir}${MINGW_PREFIX}/usr/bin/onelab.py" \
        "${pkgdir}${MINGW_PREFIX}/lib/python3.4/site-packages/onelab.py"
   rm "${pkgdir}${MINGW_PREFIX}/bin/onelab.py"

   install -D -m 644 "${srcdir}/${_realname}-${pkgver}-source/doc/LICENSE.txt" \
    "${pkgdir}${MINGW_PREFIX}/share/licenses/$pkgname/LICENSE.txt"
   install -D -m 644 "${srcdir}/${_realname}-${pkgver}-source/doc/CREDITS.txt" \
    "${pkgdir}${MINGW_PREFIX}/share/licenses/$pkgname/CREDITS.txt"

   rm -rf ${pkgdir}${MINGW_PREFIX}/usr/share/doc
}