Evaluating the access rights for a Thumbnail in DSpace XMLUI

XmluiThumbnailPermission.xsl

    <xsl:template name="gu-thumbnail-link">
        <xsl:param name="thumb" select="."/>
        <xsl:param name="src"/>
        <xsl:variable name="thumbmets" select="$EXTMETS//mets:fileSec/mets:fileGrp[@USE='THUMBNAIL']/mets:file[@GROUPID=$thumb/@GROUPID]"/>
        <xsl:variable name="authid" select="$thumbmets/@ADMID"/>
        <xsl:variable name="thumbauth" select="$EXTMETS//mets:rightsMD[@ID=$authid]"/>
        <xsl:variable name="angrec" select="$thumbauth//metsrights:Context[@in-effect='true'][@CONTEXTCLASS='MANAGED GRP'][metsrights:UserName[text()=$GUCOMM]]"/>
        <xsl:variable name="pubrec" select="$thumbauth//metsrights:Context[@in-effect='true'][@CONTEXTCLASS='GENERAL PUBLIC']"/>
        
        <xsl:choose>           
            <xsl:when test="($angrec and $AUTH='yes') or ($pubrec)">
                <div class="artifact-preview">
                    <div class="thumbnail">
                        <xsl:variable name="thumbimg">
                            <img alt="Thumbnail">
                                 <xsl:attribute name="src">
                                      <xsl:value-of select="$src" />
                                 </xsl:attribute>
                                 <xsl:if test="$MICROTAG != $SCH_VID">
                                     <xsl:attribute name="itemprop">thumbnailUrl</xsl:attribute>
                                     <xsl:attribute name="content">
                                        <xsl:value-of select="$src" />
                                     </xsl:attribute>
                                 </xsl:if>
                            </img>
                        </xsl:variable>
                        <xsl:choose>
                            <xsl:when test="$FULLMODE">
                                <a href="{mets:FLocat[@LOCTYPE='URL']/@xlink:href}">
                                    <xsl:copy-of select="$thumbimg"/>
                                </a>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:copy-of select="$thumbimg"/>
                            </xsl:otherwise>
                        </xsl:choose>
                    </div> 
                </div>
            </xsl:when>
            <xsl:otherwise>
               <div class="artifact-preview">Restricted Access</div>
            </xsl:otherwise>            
        </xsl:choose>
    </xsl:template>