PDF Extract - Extracts all PDF from a given Location while preserving the filetree (DKM)

PDF-Extract.bat

:: Einstellungen
SET FOLDER_ROOT="..\CAD-DATEN"
SET FOLDER_CAD="CAD PDF"
SET FOLDER_PRODUCT="Produkt PDF"
SET PRODUCT_EXCLUDE_PREFIX=W-


::  ----------------------------------------------------------------------------------------------
:: |                         DO NOT TOUCH THE CODE BEHIND THIS LINE                               |
::  ----------------------------------------------------------------------------------------------

@ECHO off
COLOR 1F


:: Hauptprogramm
:MAIN
CALL :SHOW_HEADER
IF NOT EXIST exclude_folders.txt (ECHO > exclude_folders.txt)

ECHO PDF Extract wird alle PDF aus dem Ordner %FOLDER_ROOT% kopieren und unter
ECHO Beibehaltung der urspruenglichen Ordnerstruktur im Verzeichnis %FOLDER_CAD%
ECHO ablegen.
ECHO.
ECHO Zusaetzlich wird ein Ordner %FOLDER_PRODUCT% erstellt, in welchen nur die PDFs
ECHO kopiert werden, welche nicht mit "%PRODUCT_EXCLUDE_PREFIX%" anfangen.
ECHO.
ECHO Um Ordner von der Suche auszuschliessen, koennen die Ordnernamen untereinander
ECHO in die beim ersten Start angelegten "exclude_folders.txt" geschrieben werden.
ECHO.

ECHO Vorgang fortsetzen? (j / n)
SET /P ARG=
IF  /I '%ARG%' == 'j' GOTO BEGIN
IF  /I '%ARG%' == 'n' GOTO CANCEL
ECHO Ungueltige Antwort
GOTO MAIN


:BEGIN
CALL :SHOW_HEADER

:: Uncomment this lines to delete existing folders before copying
:: ECHO Loesche alte Daten, bitte warten...
:: IF EXIST %FOLDER_CAD% (RD /S /Q %FOLDER_CAD%)
:: IF EXIST %FOLDER_PRODUCT% (RD /S /Q %FOLDER_PRODUCT%)
:: ECHO.

ECHO Kopiere die CAD PDFs. Bitte warten...
XCOPY %FOLDER_ROOT%\*.pdf %FOLDER_CAD% /EXCLUDE:+exclude_folders.txt /SIQYHR
ECHO.

ECHO Kopiere die Produkt-PDF. Bitte warten...
ECHO %PRODUCT_EXCLUDE_PREFIX% > exclude_file.txt
XCOPY %FOLDER_CAD%\*.pdf %FOLDER_PRODUCT% /EXCLUDE:exclude_file.txt+exclude_folders.txt /SIQYHR
DEL exclude_file.txt
ECHO.

ECHO Vorgang abgeschlossen. Danke fuer die Nutzung von PDF Extract!
ECHO (c)2012 Thomas Feldmann
GOTO END


:CANCEL
CALL :SHOW_HEADER
ECHO Es wurden keine Aenderungen vorgenommen.
GOTO END


:: Zeichnen des Headers
:SHOW_HEADER
CLS
ECHO "============================================================================"
ECHO "         ____  ____  ______   _______  ____________  ___   ____________     "
ECHO "        / __ \/ __ \/ ____/  / ____/ |/ /_  __/ __ \/   | / ____/_  __/     "
ECHO "       / /_/ / / / / /_     / __/  |   / / / / /_/ / /| |/ /     / /        "
ECHO "      / ____/ /_/ / __/    / /___ /   | / / / _, _/ ___ / /___  / /         "
ECHO "     /_/   /_____/_/      /_____//_/|_|/_/ /_/ |_/_/  |_\____/ /_/          "
ECHO "                                                                            "
ECHO "============================================================================"
ECHO.
GOTO :EOF


:END
ECHO.
PAUSE