gistfile1.coffee

$ ->
  map = new google.maps.Map $("#map-canvas")[0], 
    zoom: 1
    mapTypeId: google.maps.MapTypeId.ROADMAP
  map.setCenter new google.maps.LatLng(0, 0)

  addMarker = (long, lat) ->
    new google.maps.Marker 
      position: new google.maps.LatLng long, lat
      map:      map

  conferences =
    [{name:  "GOTO; Aarhus",   price: 10, tick:  addMarker  56.08,  10.11},
     {name:  "YOW! Melbourne", price: 4,  tick:  addMarker -37.47, 144.58}]

  do ->
    for data in conferences
      do (data) ->
        google.maps.event.addListener data.tick, "click", (mouseEvent) -> 
          console.log "Clicked #{data.name}"

  updatePriceLabel = (lo, hi) ->
    $("#price").val("$#{lo} - #{hi}")

  updateVisibleTicks = (lo, hi) ->
    data.tick.setVisible lo <= data.price <= hi for data in conferences

  do ->
    $("#slider-range").slider 
      range:   true
      min:     0
      max:     20
      values:  [5, 11]
      slide: (event, ui) ->
        updatePriceLabel ui.values[0], ui.values[1]
        updateVisibleTicks ui.values[0], ui.values[1]
    updatePriceLabel $("#slider-range").slider("values", 0), $("#slider-range").slider("values", 1)
    updateVisibleTicks $("#slider-range").slider("values", 0), $("#slider-range").slider("values", 1)