Conway's Game of Life written in Elixir

lifegame.exs

defmodule LifeGame do

  def advance(board) do
    board |> neighbors_all |> MapSet.to_list |> Enum.filter(&living?(&1, board)) |> MapSet.new
  end

  defp living?(point, board) do
    count = point |> neighbors |> Enum.count(&MapSet.member?(board, &1))
    count == 3 || (MapSet.member?(board, point) && count == 2)
  end

  defp neighbors_all(board) do
    MapSet.union(board, MapSet.new(Enum.flat_map(board, &neighbors/1)))
  end

  defp neighbors(point) do
    {x, y} = point
    [
      {x + 1, y},
      {x - 1, y},
      {x, y + 1},
      {x, y - 1},
      {x + 1, y + 1},
      {x + 1, y - 1},
      {x - 1, y + 1},
      {x - 1, y - 1},
    ]
  end
end

print_board = fn state ->
  Enum.map(0..10, fn y ->
    Enum.map(0..10, fn x ->
      if MapSet.member?(state, {x, y}) do
        "*"
      else
        "-"
      end
    end)
  end) |> Enum.join("\n")
end

state = [{0, 1}, {1, 2}, {2, 0}, {2, 1}, {2, 2}] |> MapSet.new
print_board.(state) |> IO.puts

0..100 |> Enum.reduce(state, fn _, state ->
  Process.sleep(500)
  IO.puts("\u{1b}[15A\r")
  new_state = state |> LifeGame.advance
  new_state |> print_board.() |> IO.puts
  new_state
end)