light-locker-git PKGBUILD

light-locker-libsystemd-login.patch

--- light-locker.orig/configure.ac.in	2016-08-30 10:52:46.843809660 +0800
+++ light-locker/configure.ac.in	2016-08-30 10:52:23.564394873 +0800
@@ -424,7 +424,7 @@ AC_ARG_WITH(systemd,
             [with_systemd=$withval], [with_systemd=auto])
 
 PKG_CHECK_MODULES(SYSTEMD,
-                  [libsystemd-login],
+                  [libsystemd],
                   [have_systemd=yes], [have_systemd=no])
 
 if test "x$with_systemd" = "xauto" ; then

PKGBUILD

pkgname=light-locker-git
pkgver=1.7.0.f498dc3
pkgrel=1
pkgdesc='A simple session locker for LightDM'
arch=('i686' 'x86_64')
url='https://github.com/the-cavalry/light-locker'
license=('GPL2')
depends=('dbus-glib' 'gtk3' 'libxxf86misc' 'lightdm' 'libxss')
makedepends=('git' 'gnome-common' 'intltool')
provides=('light-locker')
conflicts=('light-locker')
source=('git+https://github.com/the-cavalry/light-locker.git'
        'light-locker-libsystemd-login.patch')
sha256sums=('SKIP'
            '6645624e195f7cc114b95d323dfd55c03bbdf6b01de10e694df6a97d5ef6eeaf')

pkgver() {
  cd light-locker

  printf "%s" "$(git describe --tags | sed 's/-/.r/; s/-g/./; s/^v//')"
}

prepare() {
  cd light-locker

  patch -Np1 -i ../light-locker-libsystemd-login.patch
}

build () {
  cd light-locker

  ./autogen.sh \
    --prefix='/usr' \
    --localstatedir='/var' \
    --sysconfdir='/etc' \
    --with-x \
    --with-dpms-ext \
    --with-mit-ext \
    --with-xf86gamma-ext \
    --with-systemd \
    --without-console-kit \
    --without-upower \
    --disable-schemas-compile \
    --disable-static
  make
}

package() {
  cd light-locker

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: