fix_tmods.bat

fix_tmods.bat

@echo off
if not exist "%~dp0\Trove.exe" (
  echo. Error: Couldn't find Trove.exe
  echo. Please put this .bat script inside your Trove folder and retry!
  echo. Common locations are:
  echo. "C:\Program Files (x86)\Glyph\Games\Trove\Live"
  echo. "C:\Program Files\Glyph\Games\Trove\Live"
  echo. "C:\Program Files (x86)\Steam\steamapps\common\Trove\Games\Trove\Live"
  echo. "C:\Program Files\Steam\steamapps\common\Trove\Games\Trove\Live"
  echo.&pause&goto:eof
)

echo. Make sure you are NOT running this as Administrator
echo. This script will extract all files from the client into Override folders.
echo. This will fix all issues with .tmods not working.
echo. The script will NOT overwrite your existing Override mods!
set /p test=Do you want to continue? (y/n)
if not "%test%" == "y" exit

echo. Starting... this will take about 5 minutes!

rmdir /Q /S extracted
call:extractFolder "%~dp0"

SET source="%~dp0\extracted"
SET dest="%~dp0\"

robocopy %source% %dest% *.* /S /NP /R:5 /TS /FP /XC /XO /XN /NFL /NDL

rmdir /Q /S extracted

echo.
echo. Your .tmod mods should now work again!
echo. Credit: TheSymbol and Ignitas
echo.&pause&goto:eof

:extractFolder
for /D %%f in ("%~1*") do (
  if not "%%~nf" == "extracted" (
    if exist "%~2%%~nf\index.tfi" (
      echo. extracting %~2%%~nf
      "%~dp0Trove.exe" -tool extractarchive %~2%%~nf extracted\%~2%%~nf\override
    )
    call:extractFolder "%~1%%~nf\", "%~2%%~nf\"
  )
)
goto:eof