Run cucumber with gradle with tags support

build.gradle

plugins {
    id 'java'
}

repositories {
    jcenter()
    mavenLocal()
}

def cucumberVersion = '5.5.0'

dependencies {
    testImplementation "io.cucumber:cucumber-java:${cucumberVersion}"
}

configurations {
    cucumberRuntime {
        extendsFrom testImplementation
    }
}

def tags = (findProperty('tags') == null) ? 'not @Ignore' : findProperty('tags') + ' and not @Ignore'

task cucumber() {
    dependsOn assemble, compileTestJava
    doLast {
        javaexec {
            main = "io.cucumber.core.cli.Main"
            classpath = configurations.cucumberRuntime + sourceSets.main.output + sourceSets.test.output
            args = [
                '--strict', 
                '--plugin', 'html:build/cucumber-report',
                '--plugin', 'json:build/cucumber-report/cucumber.json', 
                '--plugin', 'pretty',
                '--plugin', 'usage:cucumber-usage.json',
                '--glue', 'hellocucumber', 
                '--tags', "${tags}", 
                'features',
            ]
        }
    }
}