Little hack I use to extend Excel tables to the end of the data when using the excellent tomfaulhaber/excel-templates

excel-templates-tables.clj

(defn extend-table-to-end! [table worksheet]
  (try
    (let [start (.getStartCellReference table)
          end   (.getEndCellReference table)
          last-row-num (.getPhysicalNumberOfRows worksheet)
          ;; Excel doesn't like zero-sized tables.
          last-row-num (if (=  last-row-num (.getRow start))
                         (inc last-row-num)
                         last-row-num)
          new-range (-> (CellRangeAddress. (.getRow start) last-row-num
                                           (.getCol start) (.getCol end))
                        .formatAsString)]
      (-> table .getCTTable (.setRef new-range)))
    (catch Exception e
      (println (format
                "Ignoring error '%s' when extending table in worksheet: '%s'"
                (.getMessage e) (excel/sheet-name worksheet))))))

(defn extend-all-tables-to-end! [path]
  (let [workbook (->> path
                      excel/load-workbook)
        tables (->> workbook
                    excel/sheet-seq
                    (mapcat (fn [worksheet]
                              (->> worksheet
                                   .getTables
                                   (map (fn [table]
                                          {:table table
                                           :worksheet worksheet})))))
                    doall)]
    (doseq [{:keys [table worksheet]} tables]
      (extend-table-to-end! table worksheet))
    (with-open [out (java.io.FileOutputStream. path)]
      (do (.write workbook out)
          (.flush out)))))