Zsh completion for evince

_evince

#compdef evince

local arguments
arguments=(
  '(-h --help --help-all --help-sm-client --help-gtk)'{-h,--help}'[show help options]'
  '(-h --help --help-sm-client --help-gtk)--help-all[show all help options]'
  '(-h --help --help-all --help-gtk)--help-sm-client[show session management options]'
  '(-h --help --help-all --help-sm-client)--help-gtk[show GTK+ Options]'
  '--sm-client-disable[disable connection to session manager]'
  '--sm-client-state-file=[specify file containing saved configuration]'
  '--sm-client-id=[specify session management ID]'
  '--class=[program class as used by the window manager]'
  '--name=[program name as used by the window manager]'
  '--gtk-module=[load additional GTK+ modules]'
  '--g-fatal-warnings=[make all warnings fatal]'
  '(-p --page-label)'{-p,--page-label=}'[the page label of the document to display]'
  '(-i --page-index)'{-i,--page-index=}'[the page number of the document to display]'
  '(-f --fullscreen)'{-f,--fullscreen}'[run evince in fullscreen mode]'
  '(-s --presentation)'{-s,--presentation}'[run evince in presentation mode]'
  '(-w --preview)'{-w,--preview}'[run evince as a previewer]'
  '(-l --find)'{-l,--find=}'[the word or phrase to find in the document]'
  '--display=[X display to use]'
  '*:PostScript or PDF file:_pspdf'
)
_arguments -s $arguments