PEP517 requirements in mach-nix

default.nix

{mach-nix, pkgs ? import <nixpkgs> {}, lib ? pkgs.lib}:
let 
  extract-metadata = import ./extract-metadata.nix { inherit lib mkPython pkgs; };
  buildPythonApplication = {...}@args: let                                                 
    metadata = extract-metadata { inherit (args) python src providers; };
    requirements = lib.concatStringsSep "\n" metadata.requires_dist;                       
  in                                                                                       
    mach-nix.buildPythonApplication ({ inherit requirements; } // args);                                                                                        
in
  buildPythonApplication { ... };

extract-metadata.nix

{lib, mkPython, pkgs}: {src, python, providers}:
let
  pyproject-toml = "${src}/pyproject.toml";
  default-build-system = {
    requires = ["setuptools >= 40.8.0" "wheel"];
    build-backend = "setuptools.build_meta:__legacy__";
  };
  build-system = if builtins.pathExists pyproject-toml then
    let 
      toml = builtins.fromTOML (builtins.readFile pyproject-toml);
    in toml.build-system
  else default-build-system; 
  base-env = mkPython {
    inherit python providers;
    requirements = ''
      pep517
      importlib-metadata >= 4.0.0
    '';
  };
  build-env = mkPython {
    inherit python providers;
    requirements = lib.concatStringsSep "\n" build-system.requires;
  };
  extract = let
    args = lib.escapeShellArgs [build-env.interpreter build-system.build-backend build-system.backend-path or ""];  
  in pkgs.runCommand "python-metadata.json" {}
    ''
    ${base-env.interpreter} ${./extract-metadata.py} $out ${src} ${args}
    '';
in
  builtins.fromJSON (builtins.readFile extract)

extract-metadata.py

import json
import sys

from importlib_metadata import Distribution
from pep517.wrappers import Pep517HookCaller

_, out, source, python, backend, backend_path = sys.argv

hooks = Pep517HookCaller(
    source, build_backend=backend, python_executable=python, backend_path=backend_path
)
dist = Distribution.at(hooks.prepare_metadata_for_build_wheel("."))

with open(out, "x") as f:
    json.dump(dist.metadata.json, f)