dynamic_conf_group.slax

version 1.1;

ns junos = "http://xml.juniper.net/junos/*/junos";
ns xnm = "http://xml.juniper.net/xnm/1.1/xnm";
ns jcs = "http://xml.juniper.net/junos/commit-scripts/1.0";

import "../import/junos.xsl";


match configuration {

    var $rpc = <get-configuration database-path=$junos-context/commit-context/database-path>;
    var $config = jcs:invoke($rpc);

    var $group_name = "ND6";
    var $nd6_stale_time = "600";
    var $int_type = "irb";

    <change> {
        <groups> {
            <junos:comment> "Group content is populated by " _ $script;
            <name> $group_name;
            <interfaces> {
                <interface operation="replace"> {
                    <name> $int_type;
                    for-each ($config/interfaces/interface[name == $int_type]/unit/family/inet6) {
                        <unit> {
                            <name> ../../name;
                            <family> {
                                <inet6> {
                                    <nd6-stale-time> $nd6_stale_time;
                                }
                            }
                        }
                    }
                }
            }
        }
    }
}