Excel VBA subroutine to split a multi-value column into multiple boolean columns

SplitCol.vba

' Split the selected column containing values like "a;b;c", "a;c" into boolean
' 0/1 columns for each of "a", "b", "c".
Sub SplitCol()
    Dim c As Range
    Dim newCols As Object
    Dim ncols As Long
    ncols = 0
    Set newCols = CreateObject("Scripting.Dictionary")
    For Each c In Intersect(ActiveSheet.UsedRange, Selection.EntireColumn).Offset(1)
        Dim s As Variant
        For Each s In Split(c.Value, ";")
            s = Trim(s)
            If s = "" Then GoTo NextSplit
            If newCols.Exists(s) Then
                Cells(c.Row, Selection.Column + newCols.Item(s)) = 1
            Else
                ncols = ncols + 1
                ActiveSheet.Columns(Selection.Column + ncols).Insert
                Cells(1, Selection.Column + ncols) = s
                Call newCols.Add(s, ncols)
                Cells(c.Row, Selection.Column + ncols) = 1
            End If
NextSplit:
        Next
    Next
    Intersect(ActiveSheet.UsedRange, _
              Range(Columns(Selection.Column + 1), _
                    Columns(Selection.Column + ncols))) _
    .SpecialCells(xlCellTypeBlanks) = 0
End Sub