backbone-queue.js.coffee

# saves are queued on a per-model-instance (aka "cid") basis...

Backbone.Model.prototype.saveWithoutQueue = Backbone.Model.prototype.save

Backbone.Model.prototype.save = (key, value, options) ->
  if _.isObject(key) or not key? # flip 'em
    options = value
    value = null
  options = (if options then _.clone(options) else {})

  success = options.success
  options.success = (model, resp) ->
    success model, resp if success
    if 0 is jQuery(document).queue(model.cid).length
      # we were the last ones
      model.queueHasBeenStarted = false
    else
      # run the next one in the queue
      jQuery(document).dequeue model.cid 

  error = options.error
  options.error = (model, resp) ->
    error model, resp if error
    if 0 is jQuery(document).queue(model.cid).length
      # we were the last ones
      model.queueHasBeenStarted = false
    else
      # run the next one in the queue
      jQuery(document).dequeue model.cid 

  if _.isObject(key) or not key? # flip 'em back
    value = options
    options = null
  jQuery(document).queue @cid, _.bind(->
    @saveWithoutQueue key, value, options
  , this)
  unless @queueHasBeenStarted
    @queueHasBeenStarted = true
    jQuery(document).dequeue @cid