gosund-wp3-serial-flash-jig.scad

/*

Jig for GoSund WP3 Serial Flash
Version 3.0

Created May 27, 2021
Modified May 28, 2021

NOTES:

  [1] Get a hammer.  Do either [A] or [B] below (I did [A]):

      [A] Print this:
          https://www.thingiverse.com/thing:4837167
          
      [B] Get a 2 inch to 1.5 inch PVC reducer as shown
          in the linked instructable in step [3] below.

      Take it easy but get your message across to your
      smart plug(s).

  [2] Render this in openSCAD and send to your slicer.

      Ender-3 V2
      Hatchbox PLA (probably doesn't matter that much)
      My 0.4 mm nozzle was okay.
      Layer height 0.12 mm
        * It's very small so it
          won't take long.
        * That level of detail may
          not be necessary.

      I had to use some bed adhesive because of the
      print size.  I like this:
      https://amzn.com/B079984GV5

  [3] See this instructable:
      https://www.instructables.com/Downloading-Tasmota-Onto-a-Gosund-WP5-or-WP3-Smart/

  [4] Choose [C] or [D], or both.
      I recommend [C] but it's your choice.

      [C] Bell Wire for Doorbell / Garage Opener
          SOLID, not stranded, unless you like
          frustration.        

          I had some 20 AWG wire here.  You just want
          wire that will fit in a Dupont jumper casing
          and is more stiff than flexible.

          22 AWG wire might be too flexible.

          Either pop off a couple of Dupont connectors
          from existing jumper wires (not hard -- you
          need a paperclip / sewing pin / needle / etc.
          to pop the release -- check on YouTube) or 
          slap on some new connectors from your Dupont
          wire crimping set.  You do have one of those,
          right?

          Now you should have two new jumpers with
          flexible Male ends on one end.  Do what you
          want with the other ends to connect to your
          UART.

      [D] Two (2) Dupont jumpers
          [Male] <---> [Male] OR
          [Male] <---> [Female] 
            * Dealer's choice (that's you, pal!)
            * To connect to USB UART or similar
              for1 ESP8266 (8285) Serial Flash

  [5] Bend the ends of your jumpers at a 90 degree
      angle.  I broke a couple of standard jumpers
      doing this (using method [D]).

  [6] Have a look at the instructable again from step [3].  It's
      informative.

  [7] Have a cold one.

  ADDITIONAL INFO:
  http://equivariant.org/gosund-wp3-esp8285.html

*/

adj = 0.17; // small adjustment
rx_slot_l = 6.32 - adj; // rx slot length - in Y direction
tx_slot_l = 5.58 - adj; // tx slot length - in X direction
slot_t = 0.85; // slot thickness
slot_x_dist = 1.78; // X dist. b/t slots
slot_y_dist = 2.15; // Y dist. b/t slots

jmp_side = 2.54 + adj; // side length Dupont jumper (0.1 inches)
jig_wall_t = 0.77; // jig wall thickness
jig_wall_h = 10.0; // jig wall height
rx_jig_w = 2 * jig_wall_t + jmp_side; // rx arm width
rx_jig_l = rx_slot_l + jmp_side/2; // rx arm length
tx_jig_w = rx_jig_w; // tx arm width
tx_jig_l = tx_slot_l + jmp_side/2; // tx arm length

cross_l = 4.4; // cross brace length (goes below pcb)
cross_h = 10.0; // cross brace height

// flip upside down for printing
rotate([180, 0, 0]) {

    difference() {

      // group these objects
      union() {

        color("red") // rx arm
          translate([
            0,
            -(rx_jig_l - slot_y_dist),
            0
          ])
          cube([
            rx_jig_w,
            rx_jig_l,
            jig_wall_h]
          );

        color("green") // tx arm
          translate([
            slot_x_dist,
            slot_y_dist - jig_wall_t,
            0
          ])
          cube([tx_jig_l, tx_jig_w, jig_wall_h]);
      }

      // subtract these objects
      color("brown") // rx jumper slot
        translate([
          jig_wall_t,
          -(rx_jig_l - slot_y_dist - jig_wall_t),
          0
        ])
        cube([
          jmp_side,
          rx_jig_l - jig_wall_t,
          jig_wall_h
        ]);

      color("blue") // tx jumper slot
        translate([
          slot_x_dist,
          slot_y_dist,
          0
        ])
        cube([
          tx_jig_l - jig_wall_t,
          jmp_side,
          jig_wall_h
        ]);
    }  

    color("violet") // rx slot brace
    translate([
      rx_jig_w/2 - slot_t/2,
      -(rx_jig_l - slot_y_dist),
      -cross_h/2
      ])
    cube([
      slot_t,
      cross_l,
      cross_h
    ]);

    color("deeppink") // tx slot brace
    translate([
      tx_jig_l + slot_x_dist - cross_l,
      slot_y_dist + jmp_side/2 - slot_t/2,
      -cross_h/2
    ])
    cube([
      cross_l,
      slot_t,
      cross_h
    ]);

}