Example assembly component

DbInsert.coffee

assembly = require '../lib/assembly'

class DbInsert extends assembly.Component
  description: 'Inserts a database record'
  # Validation of the input message is done automatically
  # before relay() method is entered
  validates:
    'db': 'func' # expect a constructor function
    'query.table': 'ok' # expect something truthy
    'query.data': 'obj' # expect an object
  relay: (msg, output) ->
    # Here we have a valid assembly message
    returning = msg.query.returning ? undefined
    # Using the data right away
    msg.db msg.query.table
    .insert msg.query.data, returning
    .then (rows) ->
      # Embedding result and passing along
      msg.rowset = rows
      msg.query = undefined
      output.sendDone msg
    .catch (err) ->
      # Oops, adding more info and passing a failed request
      err.message += ' [in DbInsert]'
      assembly.fail output, msg, err
# Named classes are encouraged for meaningful error stack traces
exports.getComponent = -> new DbInsert