TryCF Gist

trycf-gist-1713526746835-9af120b5-006e-c517-d96e-7d128f6eebab.cfm

<cfscript>

public array function queryToArrayOfStructs( required any q ) {
        try {
            var queryColumns = getMetadata( arguments.q ).map( function( item ) {
                return item.name;
            } );
        } catch ( any e ) {
            writeDump( var = arguments );
            rethrow;
        }

        return queryReduce(
            arguments.q,
            function( results, row ) {
                var rowData = structNew( "ordered" );
                for ( var column in queryColumns ) {
                    rowData[ column ] = row[ column ];
                }
                results.append( rowData );
                return results;
            }, []
        );


    }
    
public array function queryToArrayOfStructsRefactor( required any q ) {
        try {
            var queryColumns = getMetadata( arguments.q ).map( function( item ) {
                return item.name;
            } );
        } catch ( any e ) {
            writeDump( var = arguments );
            rethrow;
        }

        var results = [];
        if ( arguments.q.recordCount > 0 ) {
            arrayResize( results, arguments.q.recordCount );
        }
        for ( var row in arguments.q ) {
            var rowData = structNew( "ordered" );
            for ( var column in queryColumns ) {
                rowData[ column ] = row[ column ];
            }
            results[ arguments.q.currentRow ] = rowData;
        }
        return results;
    }
    

c = 10000;
n = 0;
seed = [];
while( n++ < c ) {
    arrayAppend( seed, { ID: n } );
}
    
q = QueryNew("id", "integer", seed);


s = getTickCount();
a = queryToArrayOfStructs(q);
e = getTickCount();

writeoutput("<hr>original #e-s# ms #arrayLen(a)#");


s = getTickCount();
a = queryToArrayOfStructsRefactor(q);
e = getTickCount();

writeoutput("<hr>refactored #e-s# ms #arrayLen(a)#");


</cfscript>