Automated cygwin installation, with thanks to http://old.nabble.com/Re%3A-Customizable-cygwin-setup.exe-p25828300.html

install.bat

@ECHO OFF
REM -- Automates cygwin installation

SETLOCAL

REM -- Change to the directory of the executing batch file
CD %~dp0

REM -- Configure our paths
SET SITE=http://mirrors.kernel.org/sourceware/cygwin/
SET LOCALDIR=%USERPROFILE%\.cache\cygwin
SET ROOTDIR=C:\cygwin64

REM -- These are the packages we will install (in addition to the default packages)
SET PACKAGES=curl,wget,openssh,rsync,git,patch,vim,pigz
SET PACKAGES=%PACKAGES%,python2,python3,python3-requests,python3-pip
SET PACKAGES=%PACKAGES%,gcc-core,gcc-g++,clang,make
SET PACKAGES=%PACKAGES%,fish,bash-completion,
SET PACKAGES=%PACKAGES%,xorg-server,xinit,xorg-docs,xterm

REM -- Do it!
ECHO *** INSTALLING PACKAGES
setup-x86_64 ^
    --quiet-mode ^
    --site "%SITE%" ^
    --root "%ROOTDIR%" ^
    --local-package-dir "%LOCALDIR%" ^
    --categories Base ^
    --packages %PACKAGES% ^
    --upgrade-also ^
    --wait

REM -- Show what we did
ECHO.
ECHO.
ECHO cygwin installation updated
ECHO  - %PACKAGES%
ECHO.

ENDLOCAL

PAUSE
EXIT /B 0